1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
dnl Copyright (C) 2009 Sun Microsystems
dnl This file is free software; Sun Microsystems
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.
AC_DEFUN([_PANDORA_SEARCH_LIBINNODB],[
AC_REQUIRE([AC_LIB_PREFIX])
dnl --------------------------------------------------------------------
dnl Check for libhaildb or libinnodb
dnl --------------------------------------------------------------------
AC_ARG_ENABLE([libinnodb],
[AS_HELP_STRING([--disable-libinnodb],
[Build with libinnodb support @<:@default=on@:>@])],
[ac_enable_libinnodb="$enableval"],
[ac_enable_libinnodb="yes"])
AS_IF([test "x$ac_enable_libinnodb" = "xyes"],[
AC_LIB_HAVE_LINKFLAGS(haildb,,[
#include <haildb.h>
],[
ib_u64_t
ib_api_version(void);
])
AS_IF([test "x${ac_cv_libhaildb}" = "xyes"],[
AC_DEFINE([HAVE_HAILDB_H],[1],[Do we have haildb.h])
INNODB_LIBS="${LTLIBHAILDB}"
ac_cv_have_innodb=yes
],[
AC_LIB_HAVE_LINKFLAGS(innodb,,[
#include <embedded_innodb-1.0/innodb.h>
],[
ib_u64_t
ib_api_version(void);
])
AS_IF([test "x${ac_cv_libinnodb}" = "xyes"],[
AC_DEFINE([HAVE_INNODB_H],[1],[Do we have innodb.h])
INNODB_LIBS="${LTLIBINNODB}"
ac_cv_have_innodb=yes
])
])
],[
ac_cv_libhaildb="no"
ac_cv_libinnodb="no"
])
AC_SUBST([INNODB_LIBS])
AM_CONDITIONAL(HAVE_LIBINNODB, [test "x${ac_cv_have_innodb}" = "xyes"])
])
AC_DEFUN([PANDORA_HAVE_LIBINNODB],[
AC_REQUIRE([_PANDORA_SEARCH_LIBINNODB])
])
AC_DEFUN([PANDORA_REQUIRE_LIBINNODB],[
AC_REQUIRE([PANDORA_HAVE_LIBINNODB])
AS_IF([test "x${ac_cv_libinnodb}" = "xno"],
AC_MSG_ERROR([libhaildb or libinnodb is required for ${PACKAGE}]))
])
|